; Installer script for XPKDT
; $VER: Install XPKDT 39.1 (21.11.95)

(complete 0)

(set @l-dest "LIBS:DataTypes/")
(set @permanent-dest "DEVS:DataTypes/")
(set @default-dest "SYS:Storage/DataTypes/")

(set #dt "Libs/DataTypes/xpk.datatype")
(set #recog "Devs/DataTypes/")

; ***************************************************************************
; English strings

(set #bad-kick
	(cat "You must have AmigaDOS 3.0 or higher to use XPKDT!"))

(set #welcome
	(cat "\nXPKDT installation\n\n\n"
       "This script installs XPKDT 1.0\n"
       "on your Amiga.\n\n\n\n"
       "XPKDT is\n"
       "Copyright  1995 Michal Letowski\n"
       "All rights reserved.\n\n"))

(set #where-driver
	(cat "Should XPKDT be installed permanently?"))

(set #where-help
	(cat "\nDataTypes can be installed as Permanently Enabled"
	     " or Manually Selectable.\n"
       "Pemanently Enabled means that the DataType is always"
       " ready for use.\n"
       "Manually Selectable means that the datatype has to be"
       " activated before it can be used.\n"))

; ***************************************************************************
; Install XPKDT

; Check AmigaDOS version
(set #version (/ (getversion) 65536))
(if (< #version 39)
	(
		(abort #bad-kick)
	)
)

(message #welcome)

(welcome)
(set old_level @user-level)

(user 2)
(set #perm
	(askbool
		(prompt #where-driver)
		(help #where-help)
		(default 0))
)
(if #perm
	(set @recog-dest @permanent-dest)
	(set @recog-dest @default-dest)
)

; Do copy
(user old_level)

; Copy library
(copylib
	(source #dt)
	(dest @l-dest)
)
(complete 40)

; Copy recog
(copyfiles
	(source #recog)
	(dest @recog-dest)
	(all)
)
(complete 80)

; Activate descriptors if Permanently enabled
(if #perm
	(run "AddDataTypes REFRESH")
)

(set @default-dest "")
(exit)
